mirror of
https://github.com/wang-bin/QtAV.git
synced 2026-10-28 19:16:48 +08:00
wang-bin
7a13caa941
- OpenGL improvement and better performance(works on iOS and Android): * enable GLSL if supported * use GLSL to render YUV frames * GLSL based video equalizer - XV bug fix and improvement. Supports NV12. Supports video equalizer. - Play from QIODevice support - Capture YUV frames support. - Fix wrong duration in OSD - CUDA decoder working in progress - player: * no gui blocking while opening a stream * add config dialog - Regressions: * OpenGL can not display H10p
61 lines
1.5 KiB
Prolog
61 lines
1.5 KiB
Prolog
include(root.pri)
|
|
|
|
TEMPLATE = subdirs
|
|
CONFIG -= ordered
|
|
SUBDIRS = libqtav
|
|
libqtav.file = src/libQtAV.pro
|
|
greaterThan(QT_MAJOR_VERSION, 4) {
|
|
qtHaveModule(quick) {
|
|
SUBDIRS += libqmlav
|
|
libqmlav.file = qml/libQmlAV.pro
|
|
libqmlav.depends += libqtav
|
|
examples.depends += libqmlav
|
|
}
|
|
}
|
|
!no-examples {
|
|
SUBDIRS += examples
|
|
examples.depends += libqtav
|
|
}
|
|
!no-tests {
|
|
SUBDIRS += tests
|
|
tests.depends += libqtav
|
|
}
|
|
OTHER_FILES += README.md TODO.txt Changelog
|
|
OTHER_FILES += templates/vo.h templates/vo.cpp templates/COPYRIGHT.h templates/mkclass.sh
|
|
OTHER_FILES += \
|
|
templates/base.h templates/base.cpp templates/base_p.h \
|
|
templates/derived.h templates/derived.cpp templates/derived_p.h \
|
|
templates/final.h templates/final.cpp
|
|
#OTHER_FILES += config.test/mktest.sh
|
|
|
|
|
|
EssentialDepends = avutil avcodec avformat swscale
|
|
OptionalDepends = \
|
|
swresample \
|
|
avresample \
|
|
gl
|
|
# no-xxx can set in $$PWD/user.conf
|
|
!no-openal: OptionalDepends *= openal
|
|
!no-portaudio: OptionalDepends *= portaudio
|
|
!no-direct2d: OptionalDepends *= direct2d
|
|
!no-gdiplus: OptionalDepends *= gdiplus
|
|
# why win32 is false?
|
|
!no-dxva: OptionalDepends *= dxva
|
|
unix {
|
|
!no-xv: OptionalDepends *= xv
|
|
!no-vaapi: OptionalDepends *= vaapi
|
|
!no-cedarv: OptionalDepends *= libcedarv
|
|
}
|
|
|
|
runConfigTests()
|
|
!config_avresample:!config_swresample {
|
|
error("libavresample or libswresample is required. Setup your environment correctly then delete $$BUILD_DIR/.qmake.conf and run qmake again")
|
|
}
|
|
|
|
|
|
PACKAGE_VERSION = 1.3.2
|
|
PACKAGE_NAME= QtAV
|
|
|
|
include(pack.pri)
|
|
#packageSet(1.3.2, QtAV)
|