// Top-level build file where you can add configuration options common to all sub-projects/modules.
import org.gradle.util.VersionNumber

buildscript {
    repositories {
        mavenCentral()
        maven { url "https://mirrors.tencent.com/nexus/repository/maven-public/" }
        maven { url "https://mirrors.tencent.com/repository/maven/liteavsdk/" }
        maven { url 'https://developer.huawei.com/repo/' }
        maven { url 'https://developer.hihonor.com/repo' }
    }
    dependencies {
        VersionNumber currentGradleVersion = VersionNumber.parse(gradle.gradleVersion)
        if (currentGradleVersion.major >= 8) {
            classpath 'com.android.tools.build:gradle:8.0.2'
        } else if (currentGradleVersion.major >= 7) {
            classpath 'com.android.tools.build:gradle:7.0.0'
        } else {
            classpath 'com.android.tools.build:gradle:4.2.0'
        }
        classpath 'com.google.gms:google-services:4.3.15'
        classpath 'com.huawei.agconnect:agcp:1.6.0.300'
        classpath 'com.hihonor.mcs:asplugin:2.0.1.300'

        if (currentGradleVersion.major >= 8) {
            classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:1.9.0"
        } else {
            classpath "org.jetbrains.kotlin:kotlin-gradle-plugin:1.5.31"
        }

        // NOTE: Do not place your application dependencies here; they belong
        // in the individual module build.gradle files
    }
}

allprojects {
    repositories {
        mavenCentral()
        maven { url "https://mirrors.tencent.com/nexus/repository/maven-public/" }
        maven { url "https://mirrors.tencent.com/repository/maven/liteavsdk/" }
        maven { url 'https://developer.huawei.com/repo/' }
        maven { url 'https://developer.hihonor.com/repo' }
    }

    tasks.withType(Javadoc) {
        options.addStringOption('Xdoclint:none', '-quiet')
        options.addStringOption('encoding', 'UTF-8')
        options.addStringOption('charset', 'UTF-8')
    }

}

subprojects {
    tasks.withType(Javadoc).all { enabled = false }
}

ext {
    compileSdkVersion = 33
    minSdkVersion = 23
    targetSdkVersion = 33
    versionCode = 1
    versionName = "8.7.7201"
    abiFilters = ['armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64']
    //['armeabi', 'armeabi-v7a', 'arm64-v8a', 'x86', 'x86_64']
    arguments = "-DANDROID_STL=c++_static"
    cppFlags = "-std=c++11"

    liteavSdk = "com.tencent.liteav:LiteAVSDK_Professional:12.6+"
}

task clean(type: Delete) {
    delete rootProject.buildDir
}